当前位置:首页 > 开发 > 开源软件 > 正文

VB中不规则图形热点的实现

发表于: 2006-04-02   作者:阿浊I   来源:转载   浏览次数:
vb
摘要: 所谓图形热点就是指定图形或图像上的某部分区域,当鼠标在这部分区域上单击或双击时,就像命令按钮一样会引发相应事件。笔者在VB 5中用Windows提供的三个API函数轻松实现了任何形状的图形热点,在此具体介绍这一技术的实现步骤。  首先在VB5中新建一"标准EXE工程",设置窗体Form1的ScaleMode属性为3。在窗体代码的声明部分定义如下三个API函数:  Private

所谓图形热点就是指定图形或图像上的某部分区域,当鼠标在这部分区域上单击或双击时,就像命令按钮一样会引发相应事件。笔者在VB 5中用Windows提供的三个API函数轻松实现了任何形状的图形热点,在此具体介绍这一技术的实现步骤。
  首先在VB5中新建一"标准EXE工程",设置窗体Form1的ScaleMode属性为3。在窗体代码的声明部分定义如下三个API函数:
  Private Type POINTAPI
    x As Long
    y As Long
  End Type
  Private Declare Function CreatePolygonRgn Lib "gdi32" (lpPoint As POINTAPI, _
   ByVal nCount As Long, ByVal nPolyFillMode As Long) As Long
  Private Declare Function DeleteObject Lib "gdi32"(ByVal hObject As Long) As Long
  Private Declare Function PtInRegion Lib "gdi32" (ByVal hRgn As Long,ByVal x As Long, _
   ByVal y As Long) As Long
  函数说明:CreatePolygonRgn( )函数是用来创建一个图形热点对象,lpPoint参数为形成图形热点区的第一个边界点坐标,nCount参数指出了边界点的个数(如nCount<3时,将无法形成一个封闭区域),nPolyFillMode参数指定填充模式,该函数返回图形热点对象(Long型);DeleteObject( )函数用来删除一个由hObject参数指定的对象;PtInRegion( )函数用来判断某坐标(由参数x、y指出)是否在hRgn图形热 点对象指出的热点区内,若是返回1,否则返回0。
  其次在申明部分再添入下列自定义变量:
  Const MAXCOUNT = 30 '热点区边界点的最多个数
  Dim RgnPt(MAXCOUNT) As POINTAPI '热点数组
  Dim RgnObject, RgnCount, flag As Long
  然后在Form1窗体的上方创建一个PictureBox控件,设置名称为P1 ,ScaleMode属性为3,Picture属性指定一幅BMP图像。在P1的MouseMove事件和MouseDown事件中添入下列代码:
  Private Sub P1_MouseDown(button As Integer, shift As Integer, x As Single, y As Single)
   If button = 1 Then '必须按下鼠标左键才有效
    RgnPt(RgnCount).x = x
    RgnPt(RgnCount).y = y
    RgnCount = RgnCount + 1
   End If
  End Sub
  Private Sub P1_MouseMove(button As Integer, shift As Integer, x As Single, y As Single)
   If PtInRegion(RgnObject, x, y) = 1 Then
    Label1.ForeColor = QBColor(12)
    Label1.Caption = " 进入图形热点区!鼠标形状变为沙漏状!"
    P1.MousePointer = 11 '设置鼠标形状为沙漏状
   ElseIf flag = 1 Then
    Label1.ForeColor = 0
    Label1.Caption = " 没有进入图形热点区!"
    P1.MousePointer = 0
   End If
  End Sub
  接着在P1的下方并排创建两个CommandButton控件,Caption属性分别设为"创建热点"和"使用热点", 名称分别设为CrtRgn(对应"创建热点")和DspRgn。在这两个命令按钮的下方创建一个Label控件作为操作 提示区,取默认名Label1,Caption属性设为空,BackColor设为白色, BorderStyle属性设为1,字体为黑体加粗小四号。双击CrtRgn和DspRgn,在它们的Click事件中分别添入以下代码:
  Private Sub CrtRgn_Click()
   Dim tmp As Long
   RgnCount = 0
   tmp = DeleteObject(RgnObject)
   Label1.Caption = " 在图像上单击鼠标左键来创建图形热点的范围!"+ _
    "至少应在不同位置单击三次以上,否则形不成封闭区域!"
   flag = 0
  End Sub
  Private Sub DspRgn_Click()
   RgnObject = CreatePolygonRgn(RgnPt(0), RgnCount, 1)
   flag = 1
  End Sub
  最后在窗体代码的任意位置添入Form_Load()事件:
  Private Sub Form_Load()
   ScaleMode = 3
   P1.ScaleMode = 3
  End Sub
  按F5运行后,首先单击"创建热点"按钮,在图像区域内的不同位置 单击鼠标左键,最好单击三次以上,否则形不成热点区。然后单击"使用热点"按钮,在图像框内移动鼠标,你会发现当鼠标进入热点区后, 形状变为沙漏状。本文中的程序仅为演示程序,在实际应用中,可以事先创建好热点区数组,然后在热点区的MouseDown( )事件中添入相应的代码,即可使用图形热点代替命令按钮。
  本程序在VB5/Win 95、Win 98下通过。

VB中不规则图形热点的实现

  • 0

    开心

    开心

  • 0

    板砖

    板砖

  • 0

    感动

    感动

  • 0

    有用

    有用

  • 0

    疑问

    疑问

  • 0

    难过

    难过

  • 0

    无聊

    无聊

  • 0

    震惊

    震惊

编辑推荐
下源代码 一、序言 在绝大多数的Windows应用程序中,其窗体都是使用的正规正矩的矩形窗体,例如我们常
前言 CSS 创建复杂图形的技术即将会被广泛支持,并且应用到实际项目中。本篇文章的目的是为大家开启
实验题目:不规则区域的填充算法 实验目的:验证不规则区域的填充算法 实验内容:利用VC与OpenGL,实
看到好文章,收藏一下: 看到网上有很多不规则窗体的实现,效果很酷.于是使用QT也实现了一个,QT的不
一、 引言   有两个主要原因使得Visual Basic极为流行:VB6程序员和OOP程序员。VB6程序员想要VB确
一、 引言   有两个主要原因使得Visual Basic极为流行:VB6程序员和OOP程序员。VB6程序员想要VB确
需要表述 项目中遇到一些不规则的图片作品需要合成,给一张不规则的png图片(比如圆形图片,中间是
之前一直在考虑这样一个问题,在实际生活中的光源都是有体积的,但是图形学中,很多时候我们用简单
Option Explicit Private Sub Form_Click() End End Sub Private Sub Form_Load() Dim h, d As Long
我们在系统设计开发过程中,经常会碰到这样的场景,使用全国或区域地图来作为导航入口,可以热点高亮
版权所有 IT知识库 CopyRight © 2009-2015 IT知识库 IT610.com , All Rights Reserved. 京ICP备09083238号